plugins {
    id 'org.springframework.boot' verstion '2.6.9'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'org.asciidoctor.convert' version '1.5.8' // asciidoctor 플러그인을 적용하는 것이다. HTMl, PDF 등을 포함한 다양한 형식으로 Asciidoctor 문서를 번약하기 위한 플러그인이다.
    id 'java'
}

group = 'com.woowacourse'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

ext {
    set('snippetsDir', file("build/generated-snippets")) // 아래에서 snippetsDir라는 변수를 사용하게 되는데, 이 변수를 선언하는 것이다.
}

dependencies {
    // spring
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'

    // database-driver
    runtimeOnly 'com.h2database:h2'

    // lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    // jwt
    implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.5'
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.11.5'

    // rest-assured
    testImplementation 'io.rest-assured:rest-assured:4.4.0'
    testImplementation 'io.rest-assured:spring-mock-mvc:4.4.0'

    // rest-docs
    asciidoctor 'org.springframework.restdocs:spring-restdocs-asciidoctor:2.0.5.RELEASE'
    testImplementation 'org.springframework.restdocs:spring-restdocs-mockmvc'
    testImplementation 'org.springframework.restdocs:spring-restdocs-restassured'
    // build/generated-snippets에 생긴 adoc들을 모아서 .adoc파일에서 읽어들일 수 있도록 연동해준다. 이를 통해 최종적으로 .adoc 파일을 HTML로 만들어 export해준다.
    // `testImplementation 'org.springframework.restdocs:spring-restdocs-mockmvc'`은  RestDocs를 사용할 때 mockMVC를 통해서 하기 위해 필요한 것이다. 만약 테스트를 MockMVC로 하지 않고, *`restassured`로 하고 싶다면 다른 것을 선언하면 된다.*
}

tasks.named('test') {
    outputs.dir snippetsDir // .adoc파일을 아까 작성한 scippetsDir 변수 값인 "build/generated-snippets"에 output으로 구성하는 설정이다.
    useJUnitPlatform()
} 

tasks.named('asciidoctor') {
    inputs.dir snippetsDir // .adoc파일을 아까 작성한 scippetsDir 변수 값인 "build/generated-snippets"에 input으로 구성하는 설정이다.
    dependsOn test
}

task createDocument(type: Copy) {
    dependsOn asciidoctor

    from file("build/asciidoc/html5/index.html")
    into file("src/main/resources/static")
    // 위에 선언한 `tasks.named('asciidoctor'), tasks.named('test')` 를 실행한 후, `"build/asciidoc/html5/index.html"` 의 파일을 `src/main/resources/static` 경로로 옮겨 서버에 접속해서 볼 수 있는 형태로 바꿔준다.
}

bootJar {
    dependsOn createDocument
}